Как на форме внешней обработки сделать так, чтобы при нажатии на кнопку появлялся список с пометками. Нужно сделать выбор несколькко элементов из списка

Сделать форму со списком, при нажатии на кнопку вызывать ее. И сделать обработчик оповещения для обработки значений, полученных из этой формы.

СписокЗначений.ОтметитьЭлементыАсинх()

Например, так
&НаКлиенте
Процедура Команда1(Команда)
    
    Список = Новый СписокЗначений();
    Для Итер = 1 По 10 Цикл
        Список.Добавить("Позиция " + Итер);
    КонецЦикла;
    
    ОписаниеОповещения = Новый ОписаниеОповещения("ВыборИзСпискаЗавершение", ЭтотОбъект);
    Список.ПоказатьОтметкуЭлементов(ОписаниеОповещения);
    
КонецПроцедуры

&НаКлиенте
Процедура ВыборИзСпискаЗавершение(Результат, ДополнительныеПараметры) Экспорт
    
    Если ТипЗнч(Результат) = Тип("СписокЗначений") Тогда
        МассивЗначений = Новый Массив();
        Для Каждого Элем Из Результат Цикл
            Если Элем.Пометка Тогда
                МассивЗначений.Добавить(Элем.Значение);
            КонецЕсли;
        КонецЦикла;
    КонецЕсли;
    
КонецПроцедуры

(2) Да, отлично, проверил
&НаКлиенте
Асинх Процедура Команда1(Команда)
    
    Список = Новый СписокЗначений();
    Для Итер = 1 По 10 Цикл
        Список.Добавить("Позиция " + Итер);
    КонецЦикла;
    
    Результат = Ждать Список.ОтметитьЭлементыАсинх();
    
КонецПроцедуры

(1) Я сам удивляюсь от возможностей списка значений. Непростой класс